Characters Strings.

Characters Strings.

The character datatype, abbreviated as char, stores letters and symbols in the Unicode format, a coding system developed to support a variety of world languages. Characters are distinguished from other symbols by putting them between single quotes (‘P’). A string is a sequence of characters. A string is noted by surrounding a group of letters with double quotes (“Processing”). Chars and strings are most often used with the keyboard methods, to display text to the screen, and to load images or files. The String datatype must be capitalized because it is a complex datatype. A String is actually a class with its own methods, some of which are featured below.


char letter;
String words = "Begin...";

void setup() {
  size(640, 360);
  // Create the font
  textFont(createFont("SourceCodePro-Regular.ttf", 36));
}

void draw() {
  background(0); // Set background to black

  // Draw the letter to the center of the screen
  textSize(14);
  text("Click on the program, then type to add to the String", 50, 50);
  text("Current key: " + letter, 50, 70);
  text("The String is " + words.length() +  " characters long", 50, 90);
  
  textSize(36);
  text(words, 50, 120, 540, 300);
}

void keyTyped() {
  // The variable "key" always contains the value 
  // of the most recent key pressed.
  if ((key >= 'A' && key <= 'z') || key == ' ') {
    letter = key;
    words = words + key;
    // Write the letter to the console
    println(key);
  }
}

Functions Used

textSize()

Sets the current font size

Learn More
size()

Defines the dimension of the display window width and height in units of pixels

Learn More
println()

The println() function writes to the console area, the black rectangle at the bottom of the Processing environment

Learn More
setup()

The setup() function is run once, when the program starts

Learn More
text()

Draws text to the screen

Learn More
textFont()

Sets the current font that will be drawn with the text() function

Learn More
keyTyped()

The keyTyped() function is called once every time a key is pressed, but action keys such as Ctrl, Shift, and Alt are ignored

Learn More
draw()

Called directly after setup(), the draw() function continuously executes the lines of code contained inside its block until the program is stopped or noLoop() is called

Learn More
background()

The background() function sets the color used for the background of the Processing window

Learn More