Array.

An array is a list of data. Each piece of data in an array is identified by an index number representing its position in the array. Arrays are zero based, which means that the first element in the array is [0], the second element is [1], and so on. In this example, an array named “coswave” is created and filled with the cosine values. This data is displayed three separate ways on the screen.

Copy



float[] coswave; 

void setup() {
  size(640, 360);
  coswave = new float[width];
  for (int i = 0; i < width; i++) {
    float amount = map(i, 0, width, 0, PI);
    coswave[i] = abs(cos(amount));
  }
  background(255);
  noLoop();
}

void draw() {

  int y1 = 0;
  int y2 = height/3;
  for (int i = 0; i < width; i++) {
    stroke(coswave[i]*255);
    line(i, y1, i, y2);
  }

  y1 = y2;
  y2 = y1 + y1;
  for (int i = 0; i < width; i++) {
    stroke(coswave[i]*255 / 4);
    line(i, y1, i, y2);
  }
  
  y1 = y2;
  y2 = height;
  for (int i = 0; i < width; i++) {
    stroke(255 - coswave[i]*255);
    line(i, y1, i, y2);
  }
  
}

Functions Used

abs()

Calculates the absolute value (magnitude) of a number

Learn More

stroke()

Sets the color used to draw lines and borders around shapes

Learn More

size()

Defines the dimension of the display window width and height in units of pixels

Learn More

map()

Re-maps a number from one range to another

Learn More

setup()

The setup() function is run once, when the program starts

Learn More

cos()

Calculates the cosine of an angle

Learn More

noLoop()

Stops Processing from continuously executing the code within draw()

Learn More

draw()

Called directly after setup(), the draw() function continuously executes the lines of code contained inside its block until the program is stopped or noLoop() is called

Learn More

line()

Draws a line (a direct path between two points) to the screen

Learn More

background()

The background() function sets the color used for the background of the Processing window

Learn More